[K/N][perf] Rewrite UI part to kts

2022-10-24 17:30:08 +02:00
parent 315b59e0d6
commit b9b2713a96
2 changed files with 60 additions and 62 deletions
@@ -1,62 +0,0 @@
-import org.jetbrains.kotlin.gradle.targets.js.webpack.KotlinWebpackConfig
-
-buildscript {
-    ext.rootBuildDirectory = file('../../..')
-
-    ext {
-        def properties = new java.util.Properties()
-        properties.load(new java.io.FileReader(project.file("$rootBuildDirectory/../gradle.properties")))
-        properties.each { k, v->
-            def key = k as String
-            def value = project.findProperty(key) ?: v
-            project.logger.info("${project.name} $key: $value")
-            set(key, value)
-        }
-    }
-
-    ext["withoutEmbedabble"] = true
-    MiscKt.kotlinInit(project, findProperty("cacheRedirectorEnabled")?.toString()?.toBoolean() ?: false)
-    ext["bootstrapKotlinRepo"] = BootstrapKt.getBootstrapKotlinRepo(project)
-    ext["bootstrapKotlinVersion"] = BootstrapKt.getBootstrapKotlinVersion(project)
-    ext["kotlinVersion"] = project.bootstrapKotlinVersion
-
-    apply from: "$rootBuildDirectory/gradle/loadRootProperties.gradle"
-    apply from: "$rootBuildDirectory/gradle/kotlinGradlePlugin.gradle"
-}
-
-plugins {
-    id("org.jetbrains.kotlin.multiplatform")
-}
-
-repositories {
-    mavenCentral()
-}
-
-
-kotlin {
-    js(IR) {
-        browser {
-            binaries.executable()
-            distribution {
-                directory = new File("$projectDir/js/")
-            }
-        }
-    }
-
-    sourceSets {
-        commonMain {
-            dependencies {
-                implementation "org.jetbrains.kotlin:kotlin-stdlib-common:$kotlinVersion"
-            }
-            kotlin.srcDir '../../benchmarks/shared/src'
-        }
-        jsMain {
-            dependencies {
-                implementation "org.jetbrains.kotlin:kotlin-stdlib-js:$kotlinVersion"
-            }
-            kotlin.srcDir 'src/main/kotlin'
-            kotlin.srcDir '../shared/src/main/kotlin'
-            kotlin.srcDir '../src/main/kotlin-js'
-        }
-    }
-}
@@ -0,0 +1,60 @@
+import org.jetbrains.kotlin.gradle.targets.js.webpack.KotlinWebpackConfig
+
+buildscript {
+    val rootBuildDirectory by extra(file("../../.."))
+
+    java.util.Properties().also {
+        it.load(java.io.FileReader(project.file("$rootBuildDirectory/../gradle.properties")))
+    }.forEach { k, v ->
+        val key = k as String
+        val value = project.findProperty(key) ?: v
+        extra[key] = value
+    }
+
+    extra["withoutEmbedabble"] = true
+    project.kotlinInit(findProperty("cacheRedirectorEnabled")?.toString()?.toBoolean() ?: false)
+    val bootstrapKotlinRepo: String? by extra(project.bootstrapKotlinRepo)
+    val bootstrapKotlinVersion: String by extra(project.bootstrapKotlinVersion)
+    val kotlinVersion: String by extra(bootstrapKotlinVersion)
+
+    apply(from = "$rootBuildDirectory/gradle/loadRootProperties.gradle")
+    apply(from = "$rootBuildDirectory/gradle/kotlinGradlePlugin.gradle")
+}
+
+plugins {
+    kotlin("multiplatform")
+}
+
+val kotlinVersion: String by extra(bootstrapKotlinVersion)
+
+repositories {
+    mavenCentral()
+}
+
+kotlin {
+    js(IR) {
+        browser {
+            binaries.executable()
+            distribution {
+                directory = project.file("js")
+            }
+        }
+    }
+
+    sourceSets {
+        val commonMain by getting {
+            dependencies {
+                implementation("org.jetbrains.kotlin:kotlin-stdlib-common:$kotlinVersion")
+            }
+            kotlin.srcDir("../../benchmarks/shared/src")
+        }
+        val jsMain by getting {
+            dependencies {
+                implementation("org.jetbrains.kotlin:kotlin-stdlib-js:$kotlinVersion")
+            }
+            kotlin.srcDir("src/main/kotlin")
+            kotlin.srcDir("../shared/src/main/kotlin")
+            kotlin.srcDir("../src/main/kotlin-js")
+        }
+    }
+}