[repo] Migrate settings.gradle into settings.gradle.kts

gradle/libs.versions.toml

@@ -6,7 +6,7 @@ gradle-toolchains-foojay-resolver = "0.4.0"
 kotlinx-serialization = "1.5.0"
 
 [libraries]
-gradle-customUserData-gradle-plugin = { module = "com.gradle:common-custom-user-data-gradle-plugin", version.ref = "gradle-custom-user-data" }
-gradle-enterprise-gradle-plugin = { module = "com.gradle:gradle-enterprise-gradle-plugin", version.ref = "gradle-enterprise" }
-gradle-toolchainsFoojayResolver-gradle-plugin = { module = "org.gradle.toolchains:foojay-resolver", version.ref = "gradle-toolchains-foojay-resolver" }
+gradle-customUserData-gradlePlugin = { module = "com.gradle:common-custom-user-data-gradle-plugin", version.ref = "gradle-custom-user-data" }
+gradle-enterprise-gradlePlugin = { module = "com.gradle:gradle-enterprise-gradle-plugin", version.ref = "gradle-enterprise" }
+gradle-toolchainsFoojayResolver-gradlePlugin = { module = "org.gradle.toolchains:foojay-resolver", version.ref = "gradle-toolchains-foojay-resolver" }
 kotlinx-serialization-json = { module = "org.jetbrains.kotlinx:kotlinx-serialization-json", version.ref = "kotlinx-serialization" }

repo/gradle-build-conventions/settings.gradle

@@ -1,45 +0,0 @@
-pluginManagement {
-    apply from: '../scripts/cache-redirector.settings.gradle.kts'
-    apply from: '../scripts/kotlin-bootstrap.settings.gradle.kts'
-
-    includeBuild '../gradle-settings-conventions'
-
-    repositories {
-        maven { url "https://maven.pkg.jetbrains.space/kotlin/p/kotlin/kotlin-dependencies" }
-        mavenCentral()
-        google()
-        gradlePluginPortal()
-    }
-}
-
-plugins {
-    id "build-cache"
-    id "gradle-enterprise"
-    id "jvm-toolchain-provisioning"
-    id "kotlin-daemon-config"
-}
-
-File versionPropertiesFile = new File(rootProject.projectDir.parentFile, "../gradle/versions.properties")
-def versionProperties = new Properties()
-versionPropertiesFile.withInputStream {
-    versionProperties.load(it)
-}
-dependencyResolutionManagement {
-    components {
-        withModule("com.google.code.gson:gson") {
-            allVariants {
-                withDependencies {
-                    add("com.google.code.gson:gson") {
-                        version {
-                            it.require(versionProperties['versions.gson'])
-                        }
-                        because("Force using same gson version because of https://github.com/google/gson/pull/1991")
-                    }
-                }
-            }
-        }
-    }
-}
-
-include ":buildsrc-compat"
-include ":prepare-deps"

repo/gradle-build-conventions/settings.gradle.kts

@@ -0,0 +1,47 @@
+import java.util.*
+
+pluginManagement {
+    apply(from = "../scripts/cache-redirector.settings.gradle.kts")
+    apply(from = "../scripts/kotlin-bootstrap.settings.gradle.kts")
+
+    includeBuild("../gradle-settings-conventions")
+
+    repositories {
+        maven(url = "https://maven.pkg.jetbrains.space/kotlin/p/kotlin/kotlin-dependencies")
+        mavenCentral()
+        google()
+        gradlePluginPortal()
+    }
+}
+
+plugins {
+    id("build-cache")
+    id("gradle-enterprise")
+    id("jvm-toolchain-provisioning")
+    id("kotlin-daemon-config")
+}
+
+val versionPropertiesFile = File(rootProject.projectDir.parentFile, "../gradle/versions.properties")
+val versionProperties = Properties()
+versionPropertiesFile.bufferedReader().use {
+    versionProperties.load(it)
+}
+dependencyResolutionManagement {
+    components {
+        withModule("com.google.code.gson:gson") {
+            allVariants {
+                withDependencies {
+                    add("com.google.code.gson:gson") {
+                        version {
+                            require(versionProperties["versions.gson"] as String)
+                        }
+                        because("Force using same gson version because of https://github.com/google/gson/pull/1991")
+                    }
+                }
+            }
+        }
+    }
+}
+
+include(":buildsrc-compat")
+include(":prepare-deps")

repo/gradle-settings-conventions/gradle-enterprise/build.gradle.kts

@@ -14,6 +14,6 @@ kotlin.jvmToolchain(8)
 val buildGradlePluginVersion = extra.get("kotlin.build.gradlePlugin.version")
 dependencies {
     implementation("org.jetbrains.kotlin:kotlin-build-gradle-plugin:$buildGradlePluginVersion")
-    implementation(libs.gradle.enterprise.gradle.plugin)
-    implementation(libs.gradle.customUserData.gradle.plugin)
+    implementation(libs.gradle.enterprise.gradlePlugin)
+    implementation(libs.gradle.customUserData.gradlePlugin)
 }

repo/gradle-settings-conventions/jvm-toolchain-provisioning/build.gradle.kts

@@ -9,7 +9,7 @@ repositories {
 }
 
 dependencies {
-    implementation(libs.gradle.toolchainsFoojayResolver.gradle.plugin)
+    implementation(libs.gradle.toolchainsFoojayResolver.gradlePlugin)
 }
 
 kotlin.jvmToolchain(8)