kotlin-fork/plugins/kotlin-serialization/kotlin-serialization-compiler/build.gradle

buildscript {
    ext {
        kotlin_root = file("$rootDir/../../..")
        distDir = file("$kotlin_root/dist")
        bootstrapCompilerFile = file("$distDir/kotlin-compiler-for-maven.jar")
        kotlin_version = "1.1.3"
    }

    repositories {
        mavenCentral()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:${kotlin_version}"
    }
}

plugins {
    id "org.jetbrains.intellij" version "0.2.15"
}

group 'org.jetbrains.kotlinx'
version '0.1-SNAPSHOT'


apply plugin: 'kotlin'
apply plugin: 'maven-publish'

repositories {
    mavenCentral()
}

dependencies {
    compileOnly "org.jetbrains.kotlin:kotlin-stdlib:${kotlin_version}"
    compileOnly files(bootstrapCompilerFile.toString())
}

sourceSets {
    main {
        java {
            srcDir 'src'
        }
    }
}

tasks.withType(org.jetbrains.kotlin.gradle.tasks.AbstractKotlinCompile) {
    compilerJarFile = bootstrapCompilerFile
}

jar {
    from ('./src') {
        include 'META-INF/services/org.jetbrains.kotlin.compiler.plugin.ComponentRegistrar'
        include 'META-INF/plugin.xml'
    }
}


apply plugin: 'org.jetbrains.intellij'

intellij {
    if (findProperty("noIdeaSDK") == null) {
        localPath "$kotlin_root/ideaSDK"
    }
    pluginName 'Kotlin-serialization'
    downloadSources false
}