apply plugin: 'kotlin'
apply plugin: 'jps-compatible'

configurations {
    testArtifacts
}

dependencies {
    api("org.jetbrains.kotlinx:binary-compatibility-validator:0.7.1")

    testApi project(':kotlin-test:kotlin-test-junit')

    testArtifacts project(':kotlin-stdlib')
    testArtifacts project(':kotlin-stdlib-jdk7')
    testArtifacts project(':kotlin-stdlib-jdk8')
    testArtifacts project(':kotlin-reflect')
    testArtifacts project(':kotlin-gradle-plugin-idea')

    testCompileOnly("org.ow2.asm:asm-tree:9.0") {
        because(
                "Necessary to compile copied 'filterOutAnnotated' implementation. " +
                        "Can be removed after https://github.com/Kotlin/binary-compatibility-validator/pull/75"
        )
    }
}

pill {
    variant = 'FULL'
}

sourceSets {
    test {
        java {
            srcDir "src/test/kotlin"
        }
    }
}

test {
    dependsOn configurations.testArtifacts

    systemProperty 'overwrite.output', System.getProperty("overwrite.output", "false")
    systemProperty 'kotlinVersion', project.version
    systemProperty 'testCasesClassesDirs', sourceSets.test.output.classesDirs.asPath
    jvmArgs '-ea'
}