[Build] Migrate kotlin-stdlib-gen to Gradle Kotlin DSL

libraries/tools/kotlin-stdlib-gen/build.gradle.kts

@@ -1,52 +1,58 @@
-apply plugin: 'kotlin'
+plugins {
+    kotlin("jvm")
+}
+
+val copyrightDirectory = project.layout.buildDirectory.dir("copyright")
 
 sourceSets {
-    main {
+    "main" {
-        kotlin.srcDir 'src'
+        kotlin.srcDir("src")
-        resources.srcDir "$buildDir/copyright"
+        resources.srcDir(copyrightDirectory)
     }
 }
 
 dependencies {
-    api "org.jetbrains.kotlin:kotlin-stdlib:$bootstrapKotlinVersion"
+    api("org.jetbrains.kotlin:kotlin-stdlib:$bootstrapKotlinVersion")
-    api "org.jetbrains.kotlin:kotlin-reflect:$bootstrapKotlinVersion"
+    api("org.jetbrains.kotlin:kotlin-reflect:$bootstrapKotlinVersion")
 }
 
-compileKotlin {
+tasks {
-    kotlinOptions {
+    compileKotlin {
-        freeCompilerArgs = ["-version", "-Xdont-warn-on-error-suppression"]
+        compilerOptions {
+            freeCompilerArgs.addAll(listOf("-version", "-Xdont-warn-on-error-suppression"))
+        }
     }
-}
 
-tasks.register("copyCopyrightProfile", Copy) {
+    val copyCopyrightProfile by registering(Copy::class) {
-    from "$rootDir/.idea/copyright"
+        from("$rootDir/.idea/copyright")
-    into "$buildDir/copyright"
+        into(copyrightDirectory)
-    include 'apache.xml'
+        include("apache.xml")
-}
+    }
 
-processResources {
+    processResources {
-    dependsOn(copyCopyrightProfile)
+        dependsOn(copyCopyrightProfile)
-}
+    }
 
-tasks.register("run", JavaExec) {
+    register<JavaExec>("run") {
-    group 'application'
+        group = "application"
-    mainClass = 'generators.GenerateStandardLibKt'
+        mainClass = "generators.GenerateStandardLibKt"
-    classpath sourceSets.main.runtimeClasspath
+        classpath = sourceSets.main.get().runtimeClasspath
-    args = ["${rootDir}"]
+        args = listOf("$rootDir")
-    systemProperty 'line.separator', '\n'
+        systemProperty("line.separator", "\n")
-}
+    }
 
-tasks.register("generateStdlibTests", JavaExec) {
+    register<JavaExec>("generateStdlibTests") {
-    group 'application'
+        group = "application"
-    mainClass = 'generators.GenerateStandardLibTestsKt'
+        mainClass = "generators.GenerateStandardLibTestsKt"
-    classpath sourceSets.main.runtimeClasspath
+        classpath = sourceSets.main.get().runtimeClasspath
-    args = ["${rootDir}"]
+        args = listOf("$rootDir")
-    systemProperty 'line.separator', '\n'
+        systemProperty("line.separator", "\n")
-}
+    }
 
-tasks.register("generateUnicodeData", JavaExec) {
+    register<JavaExec>("generateUnicodeData") {
-    group 'application'
+        group = "application"
-    mainClass = 'generators.unicode.GenerateUnicodeDataKt'
+        mainClass = "generators.unicode.GenerateUnicodeDataKt"
-    classpath sourceSets.main.runtimeClasspath
+        classpath = sourceSets.main.get().runtimeClasspath
-    args = ["${rootDir}"]
+        args = listOf("$rootDir")
-}
+    }
+}