[K/JS] Prepare JS Plain Objects plugin to publication

2024-01-17 10:52:58 +00:00
parent 561be747c1
commit dfe2d8651e
53 changed files with 479 additions and 393 deletions
@@ -0,0 +1,42 @@
+import plugins.configureDefaultPublishing
+import plugins.configureKotlinPomAttributes
+
+description = "Runtime library for the JS Plain Objects compiler plugin"
+
+plugins {
+    kotlin("js")
+    `maven-publish`
+}
+
+group = "org.jetbrains.kotlin"
+
+kotlin {
+    js {
+        browser()
+        nodejs()
+        compilations["main"].defaultSourceSet {
+            dependencies {
+                compileOnly(kotlin("stdlib-js"))
+            }
+        }
+    }
+}
+
+val emptyJavadocJar by tasks.registering(Jar::class) {
+    archiveClassifier.set("javadoc")
+}
+
+configureDefaultPublishing()
+
+publishing {
+    publications {
+        create<MavenPublication>("maven") {
+            artifactId = "kotlin-js-plain-objects"
+            from(components["kotlin"])
+            configureKotlinPomAttributes(project, "Annotations library for the JS Plain Objects compiler plugin", packaging = "klib")
+        }
+        withType<MavenPublication> {
+            artifact(emptyJavadocJar)
+        }
+    }
+}