Gradle plugins migration to Gradle build

* Add gradle-tools subproject
* Add Gradle buildscripts to the related projects
* Remove the projects from the libraries pom.xml
* Move AndroidGradleWrapper.groovy to separate source root
* Changed artifact dependencies to project dependencies where needed
* Extract common configuration into commonConfiguration.gradle
* (convert functions to closures to be able to call them)
* Refactor DSL usage
* Replace `project.properties` with `findProperty`
* Unify Gradle wrapper between `libraries` and `gradle-tools`
(as a temporary solution, just made the wrapper files the same)

libraries/tools/kotlin-allopen/build.gradle

@@ -0,0 +1,36 @@
+apply plugin: 'kotlin'
+
+configureJvmProject(project)
+configurePublishing(project)
+
+repositories {
+    mavenLocal()
+    jcenter()
+    maven { url 'http://repository.jetbrains.com/utils' }
+}
+
+dependencies {
+    compile project(':kotlin-gradle-plugin-api')
+
+    compile "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
+    compileOnly "org.jetbrains.kotlin:kotlin-compiler-embeddable:$kotlin_version"
+
+    compileOnly 'org.jetbrains.kotlin:gradle-api:1.6'
+}
+
+def originalSrc = "$kotlin_root/plugins/allopen/allopen-cli/src"
+def targetSrc = file("$buildDir/allopen-target-src")
+
+task preprocessSources(type: Copy) {
+    from originalSrc
+    into targetSrc
+    filter { it.replaceAll('(?<!\\.)com\\.intellij', 'org.jetbrains.kotlin.com.intellij') }
+}
+
+sourceSets.main.java.srcDirs += targetSrc
+
+compileKotlin.dependsOn preprocessSources
+
+jar {
+    from(targetSrc) { include("META-INF/**") }
+}