Build: Publish jcabi-aether-1.0-SNAPSHOT to kotlin-dependencies as 1.0-dev-3

This allows to remove dependency on snapshot repository
https://oss.sonatype.org/content/repositories/snapshots

dependencies/jcabi-aether/build.gradle.kts

@@ -0,0 +1,52 @@
+plugins {
+    `java-library`
+    `maven-publish`
+    id("com.jfrog.bintray") version "1.8.4"
+}
+
+group = "org.jetbrains.kotlin"
+version = "1.0-dev-3"
+
+repositories {
+    mavenCentral()
+    maven(url = "https://oss.sonatype.org/content/repositories/snapshots")
+}
+
+val aether by configurations.creating
+dependencies {
+    aether("com.jcabi:jcabi-aether:1.0-SNAPSHOT")
+}
+
+val jar = tasks.named<Jar>("jar") {
+    from(provider {
+        provider {
+            zipTree(
+                aether.resolvedConfiguration
+                    .firstLevelModuleDependencies
+                    .single()
+                    .moduleArtifacts
+                    .single()
+                    .file
+            )
+        }
+    })
+}
+
+apply(from="../publishing.gradle.kts")
+
+configure<PublishingExtension> {
+    publications.getByName<MavenPublication>("maven") {
+        pom.withXml {
+            asNode().appendNode("dependencies").apply {
+                aether.resolvedConfiguration.firstLevelModuleDependencies.single().children.forEach {
+                    appendNode("dependency").apply {
+                        appendNode("groupId", it.moduleGroup)
+                        appendNode("artifactId", it.moduleName)
+                        appendNode("version", it.moduleVersion)
+                        appendNode("scope", "compile")
+                    }
+                }
+            }
+        }
+    }
+}

dependencies/publishing.gradle.kts

@@ -30,8 +30,8 @@ configure<PublishingExtension> {
 }
 
 configure<BintrayExtension> {
-    user = extra["bintray.user"] as String
-    key = extra["bintray.apikey"] as String
+    user = findProperty("bintray.user") as String?
+    key = findProperty("bintray.apikey") as String?
 
     setPublications("maven")