Move contents of stdlib-jdk7/8 into stdlib

#KT-51907

libraries/stdlib/jvm/build.gradle

@@ -22,6 +22,16 @@ sourceSets {
             srcDir 'src'
         }
     }
+    mainJdk7 {
+        kotlin {
+            srcDir '../jdk7/src'
+        }
+    }
+    mainJdk8 {
+        kotlin {
+            srcDir '../jdk8/src'
+        }
+    }
     test {
         kotlin {
             srcDir 'test'
@@ -39,7 +49,7 @@ sourceSets {
     }
 }
 
-LibrariesCommon.configureJava9Compilation(project, 'kotlin.stdlib', [sourceSets.main.output])
+LibrariesCommon.configureJava9Compilation(project, 'kotlin.stdlib', [sourceSets.main.output, sourceSets.mainJdk7.output, sourceSets.mainJdk8.output])
 
 configurations {
     commonSources
@@ -50,6 +60,8 @@ configurations {
         }
     }
     compileOnly.extendsFrom(builtins)
+    mainJdk7CompileOnly.extendsFrom(builtins)
+    mainJdk8CompileOnly.extendsFrom(builtins)
     testCompileOnly.extendsFrom(builtins)
 }
 
@@ -60,6 +72,10 @@ dependencies {
 
     api group: 'org.jetbrains', name: 'annotations', version:'13.0'
 
+    mainJdk7Api sourceSets.main.output
+    mainJdk8Api sourceSets.main.output
+    mainJdk8Api sourceSets.mainJdk7.output
+
     testApi project(':kotlin-test:kotlin-test-junit')
 
     builtins project(':core:builtins')
@@ -71,11 +87,19 @@ jar {
     from {
         zipTree(configurations.builtins.singleFile)
     }
+    from sourceSets.mainJdk7.output
+    from sourceSets.mainJdk8.output
     from sourceSets.java9.output
 }
 
 sourcesJar {
     from "${rootDir}/core/builtins/native"
+    from(sourceSets.mainJdk7.allSource) {
+        into 'jdk7'
+    }
+    from(sourceSets.mainJdk8.allSource) {
+        into 'jdk8'
+    }
 }
 
 task distSourcesJar(type: Jar) {
@@ -124,6 +148,28 @@ compileKotlin {
     }
 }
 
+compileMainJdk7Kotlin {
+    kotlinJavaToolchain.toolchain.use(JvmToolchain.getToolchainLauncherFor(project, JdkMajorVersion.JDK_1_7))
+    kotlinOptions.jvmTarget = "1.8"
+    kotlinOptions.freeCompilerArgs = [
+            "-Xallow-kotlin-package",
+            "-Xmultifile-parts-inherit",
+            "-Xno-new-java-annotation-targets",
+            "-opt-in=kotlin.RequiresOptIn",
+            "-opt-in=kotlin.contracts.ExperimentalContracts",
+    ]
+    kotlinOptions.moduleName = "kotlin-stdlib-jdk7"
+}
+
+compileMainJdk8Kotlin {
+    kotlinOptions.freeCompilerArgs = [
+            "-Xallow-kotlin-package",
+            "-Xmultifile-parts-inherit",
+            "-Xno-new-java-annotation-targets",
+    ]
+    kotlinOptions.moduleName = "kotlin-stdlib-jdk8"
+}
+
 compileTestKotlin {
     kotlinOptions {
         freeCompilerArgs += [

libraries/stdlib/jvm/java9/module-info.java

@@ -31,6 +31,18 @@ module kotlin.stdlib {
     exports kotlin.jvm.internal;
     exports kotlin.jvm.internal.markers;
 
+    // JDK 7
+    exports kotlin.jdk7;
+    exports kotlin.io.path;
+
+    // JDK 8
+    exports kotlin.jvm.optionals;
+    exports kotlin.jvm.jdk8;
+    exports kotlin.collections.jdk8;
+    exports kotlin.streams.jdk8;
+    exports kotlin.text.jdk8;
+    exports kotlin.time.jdk8;
+
     // Open packages with .kotlin_builtins files to kotlin-reflect, to allow reflection to load built-in declarations from there
     opens kotlin to kotlin.reflect;
     opens kotlin.annotation to kotlin.reflect;